1. Introduction

Basics

f=Series[Exp[x],{x,0,6}]

g=Normal[f]

Plot[{Exp[x],g},{x,0,5}]

Patterns and replacements

g

Length[g]

g[[5]]

g/.{x->-x}

gg=(g+%)/2

Simplify[gg]

Expand[gg]

g/.{x^n_->0}

g/.{x^n_/;OddQ[n]->0}

g/.{x^n_/;EvenQ[n]->y^n}

h=%/.x->0

Position[h,y^4]

hh=h/.y->I y

Structure

Head[hh]

FullForm[hh]

Map[F,hh]

Альтернативное обозначение :

F/@hh

Map[F,hh]/.F[(a_/;FreeQ[a,y])x_]->a F[x]

Apply[F,hh]

Альтернативное обозначение :

F@@hh

Apply[List,hh]

Apply[Times,hh]

Matrices

m={{Cos[x],Sin[x]},{Sin[x],-Cos[x]}}

m//MatrixForm

m.m

Simplify[%]//MatrixForm

2. Functions

Definition + Bessel functions

f[x_]:=BesselJ[0,x]

f=.
g=.

f[x_]:=BesselJ[0,x]
g[x_]:=BesselJ[1,x]

Plot[f[x],{x,0,10}]

Series[f[x],{x,Infinity,2}]

fa=Normal[%[[1]]]

Plot[{f[x],fa},{x,0,8},PlotStyle->{Automatic,Dashed}]

Plot[{f[x],g[x]},{x,0,8}]

Alternative definition

f[x_]:=BesselJ[0,x]

f1=BesselJ[0,#]&

f1[x]

Solution for Cos[x] == t x

Plot[{Cos[x],x},{x,0,1}]

FindRoot[Cos[x]==x,{x,1}]

FindRoot[Cos[x]==5x,{x,1}]

Φ[t_]:=FindRoot[Cos[x]==t x,{x,1}]

Φ[5]

Φ[t_]:=x/.FindRoot[Cos[x]==t x,{x,1}]

Plot[Φ[t],{t,0,5}]

Ψ[a_]:=NIntegrate[Φ[y],{y,0,a}]

Ψ[1]

Такая неприятность связана с тем, что при вычислении Φ[y] Mathematica не может сама понять, что нужно y сразу представлять в виде числа с плавающей точкой. Ей нужно подсказать, как указано ниже. Однако, чтобы она забыла предыдущее определение, проще всего перезагрузить ядро (Evaluation > Quit Kernel > Local). После чего:

Φ[t_?NumericQ]:=x/.FindRoot[Cos[x]==t x,{x,1}]

Ψ[a_?NumericQ]:=NIntegrate[Φ[y],{y,0,a}]

Ψ[1]

Plot[Ψ[z],{z,0,5}]

3. Integrals

Basics

Integrate[Exp[-a x],x]

Integrate[Exp[-a x],{x,0,1}]

Integrate[Exp[-a x^6],x]

Integrate[Exp[-a x^6]BesselJ[0,x]^2,x]

Integrate[Exp[-a x],{x,0,Infinity}]

Integrate[Exp[-a x],{x,0,Infinity},Assumptions->a>0]

Integrate[Cos[x]/(1+x^2),{x,0,Infinity}]

Integrate[((Cos[k x])/(a^2+x^2)),{x,0,Infinity}]

Integrate[((Cos[k x])/(a^2+x^2)),{x,0,Infinity},Assumptions->{k>0,a>0}]

Yukawa potential in 2D

Integrate[Exp[I p Cos[ϕ]],{ϕ,0,2Pi}]/2/π

Integrate[Exp[I p Cos[ϕ]],{ϕ,0,2Pi},Assumptions:>p>0]/2/π

Integrate[BesselJ[0,k r]k/(k^2+a^2),{k,0,Infinity},Assumptions->{r>0,a>0}]

Plot[BesselK[0,x],{x,0,3}]

Series[BesselK[0,x],{x,0,1}]

Integral with two McDonald functions

Integrate[BesselK[0,x]^2 x,x]

А вот такой уже не может, хоть он тоже выражается через функции Макдональда:

int=Integrate[BesselK[0,x]^2 x^3,x]

FullSimplify[%]

KK={((BesselK[0,x])^2),x BesselK[0,x]BesselK[1,x],((BesselK[1,x])^2)}

cc={a1+a2 x^2+a3 x^4,b1+b2 x^2+b3 x^4,c1+c2 x^2+c3 x^4}

cc.KK

d=FullSimplify[D[cc.KK,x]]-BesselK[0,x]^2 x^3

cc

cc/.x->1

vars=Flatten[Map[Apply[List,#]&,cc/.x->1]]

d

KK

Apply[List,Collect[Coefficient[d,KK[[1]]],x]]/.x->1

eqs=Map[#==0&,Flatten[Table[Apply[List,Collect[Coefficient[d,KK[[j]]],x]]/.x->1,{j,3}]]]

ss=Solve[eqs,vars]

rr=cc.KK/.ss[[1]]

FullSimplify[D[rr,x]]

2D array of resistances

R[m_,n_]:=Integrate[((1-Cos[m x+n y])/(2-Cos[x]-Cos[y])),{x,0,2π},{y,0,2π}]/(2π)^2

Timing[R[1,0]]

Timing[R[1,1]]

Timing[Expand[R[2,0]]]

Timing[Expand[R[2,1]]]

Resistance between far points in 3D and 2D

NIntegrate[(1/(3-Cos[x]-Cos[y]-Cos[z])),{x,0,2π},{y,0,2π},{z,0,2π}]/(2π)^3

NIntegrate[(1/(2-Cos[x]-Cos[y])),{x,0,2π},{y,0,2π}]/(2π)^2

Потому что это Log[r]!